metshein.com - 12 - Muu meedia kuvamine

12 - Muu meedia kuvamine

Kirjutas Mario Metshein

Piltide kuvamine

Flashis on võimalik kuvada jpg, gif ja png vormingus pilte. Pildi kuvamise kood on sarnane teksti omale, kuid erinevus seisneb just Loader'is (teksti puhul kasutasime URLLoader'it)

var req:URLRequest = new URLRequest("pilt.jpg");
var loader:Loader = new Loader();
loader.load(req);
addChild(loader);

Pildi laadimiseks luuakse konteiner aga pilti veel ei kuvata, selleks tuleb luua eraldi konteiner ja teeme seda addChild abiga.

SWF faili lugemine ning preloader kasutamine

Suurte failile laadimisel oleks hea teada, kui palju on veel laadimist jäänud. Selleks oleks hea teha nn preloader. Näites kasutame seda faili. Kasutame eelmist koodi. Vajuta Ctrl+Enter ning avanenud akna menüüst vali View>Download Settings ja vali midagi väikes, näiteks 56K ja siis vajuta uuesti Ctrl+Enter, et näha kuidas kuvatakse animatsioon aeglase ühendusega.

var req:URLRequest = new URLRequest("vesi.swf");
var loader:Loader = new Loader();
loader.load(req);
addChild(loader);

Võtab ikka jupike aega? Selle vea parandamiseks joonistame kõigepealt tekstikasti jainstance name paneme talle preload_txt. ActionScripti kirjutame nii...

var req:URLRequest = new URLRequest("vesi.swf");
var loader:Loader = new Loader();
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, failLaetud);
loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, preload);
loader.load(req);
addChild(loader);
function failLaetud(event:Event):void
{
addChild(loader);
}
function preload(event:ProgressEvent):void
{
var protsent:Number = Math.round(event.bytesLoaded / event.bytesTotal * 100);
preload_txt.text = String(protsent) + "%";
}

Hääle esitamine

Muusikafaili leiad aadressilt FlashKit.com.

Vaatame kuidas laadida muusikafaili. Põhimõtteliselt toimub see samamoodi nagu eelmiste meediafailide puhul ja kasutame Sound klassi.

var req:URLRequest = new URLRequest("podra_maja.mp3");
var sound:Sound = new Sound();
function muusika_laadimine(event:Event):void
{
sound.play();
}
sound.addEventListener(Event.COMPLETE, muusika_laadimine);
sound.load(req);

Hääle kontrollimine

Proovime nüüdnuppude abil kontrollida muusika käivitamist ja seismajätmist. Joonista kaks nuppu: play_btn ja stop_btn

var req:URLRequest = new URLRequest("podra_maja.mp3");
var sound:Sound = new Sound();
var controller:SoundChannel;
function muusika_laadimine(event:Event):void
{
controller = sound.play();
controller.stop();
play_btn.addEventListener(MouseEvent.CLICK, playSound);
stop_btn.addEventListener(MouseEvent.CLICK, stopSound);
}
function playSound(event:MouseEvent):void
{
controller = sound.play();
}
function stopSound(event:MouseEvent):void
{
controller.stop();
}
sound.addEventListener(Event.COMPLETE, muusika_laadimine);
sound.load(req);

Kui jälgid koodi tähelepanelikult siis funktsioonis muusika_laadimine() alustame kõigepealt muusika mängimist. See on vajalik, et saaks muusika kohe seisma jätta. See toimub kiiresti ja muusika algust ei kuule. Ülejäänud nupufunktsioonid on nagu ikka.

Hääletugevuse reguleerimine

Hääletugevuse kontrollimiseks kasutame SoundTransform klassi.

var req:URLRequest = new URLRequest("podra_maja.mp3");
var sound:Sound = new Sound();
var controller:SoundChannel;
var volumeControl:SoundTransform;
function muusika_laadimine(event:Event):void
{
controller = sound.play();
controller.stop();
volumeControl = controller.soundTransform;
play_btn.addEventListener(MouseEvent.CLICK, playSound);
stop_btn.addEventListener(MouseEvent.CLICK, stopSound);
up_btn.addEventListener(MouseEvent.CLICK, volumeUp);
down_btn.addEventListener(MouseEvent.CLICK, volumeDown);
}
function playSound(event:MouseEvent):void
{
controller = sound.play();
}
function stopSound(event:MouseEvent):void
{
controller.stop();
}
function volumeUp(event:MouseEvent):void
{
volumeControl.volume += 0.1;
if(volumeControl.volume > 1)
{
volumeControl.volume = 1;
}
controller.soundTransform = volumeControl;
}
function volumeDown(event:MouseEvent):void
{
volumeControl.volume -= 0.1;
if(volumeControl.volume < 0)
{
volumeControl.volume = 0;
}
controller.soundTransform = volumeControl;
}
sound.addEventListener(Event.COMPLETE, muusika_laadimine);
sound.load(req);

Häält tõstetakse 0,1 punkti võrra, kusjuures 0 on täielik vaikus ja 1 on maksimum. Funktsiooni lisame tingimuslaused, mis ei luba häälel minna üle 1 või alla 0.

Tulemus

Video mängimine ja kontrollimine

var connection:NetConnection = new NetConnection();
var stream:NetStream;
var video:Video = new Video(320,240);
var metaObj:Object = new Object();
var isPaused:Boolean = true;
function onMetaData(data:Object):void
{
}
function playVideo(event:MouseEvent):void
{
if(isPaused)
{
stream.resume();
}
else
{
stream.play("ny.f4v");
}
isPaused = false;
}
function pauseVideo(event:MouseEvent):void
{
stream.pause();
isPaused = true;
}
function stopVideo(event:MouseEvent):void
{
stream.seek(0);
stream.pause();
isPaused = true;
}
connection.connect(null);
stream = new NetStream(connection);
stream.client = metaObj;
metaObj.onMetaData = onMetaData;
video.attachNetStream(stream);
stream.play("ny.f4v");
stream.pause();
addChild(video);
video.x = 28;
video.y = 22;
play_btn.addEventListener(MouseEvent.CLICK, playVideo);
pause_btn.addEventListener(MouseEvent.CLICK, pauseVideo);
stop_btn.addEventListener(MouseEvent.CLICK, stopVideo);

Videosid soovitud formaati saad salvestada Adobe Media Encoder CS4'ga

ÜLESANNE

Kasuta eelmises ülesandes loodud kodulehele taustamuusika ning sellele kontroller, mis lubab muusikat välja lülitada ja muuta heli tugevust. (kes on vapramad, siis uurivad kuidas siduda seda arvuti "küpsistega", et kui kasutaja on hääle välja lülitanud, siis see otsus säilib, isegi kui linkidel klikkida)

Teise osana lisa kodulehele pidike video või galerii.